Function View

A user defined function can be registered as a view with addFunctionView. Once added, function views are persisted across the cluster, ensuring availability on all nodes even after a DolphinDB cluster restart.

For example, define a function myFunc and add it as a function view:

def myFunc(){
    print "myFunc"
}
addFunctionView(udf=myFunc)

Functions defined within a module can be added as views in batches by specifying the module namespace. For example, declare a module myModule and define functions f1 and f2 in the file [home]/modules/dir1/myModule.dos.

module dir1::myModule
​
def f1(){
    print "dir1::myModule::f1"
}
def f2(){
    print "dir1::myModule::f2"
}

Reference the module with use, then add all functions within the module as views by specifying the module namespace moduleName="dir1::myModule" for addFunctionView.

use dir1::myModule
addFunctionView(moduleName="dir1::myModule")

To check registered function views, use getFunctionViews. Executing getFunctionViews() returns a table as follows, displaying view myFunc along with f1 and f2 defined in myModule.

Note: Administrators can call getFunctionViews to obtain all function views, while users with VIEW_OWNER permission can only retrieve the function views they have created.

A view creator can grant a user the VIEW_EXEC privilege to execute the specified function view. Granted users can obtain the result of a function view even without the privileges to access the involved data. VIEW_EXEC can be applied to global (), module namespace (<namespace>::), or function view level. If functions of a module are added as views, the fully-qualified namespace can be used for specifying a module-level access control. For example:

// grant user1 the execution privilege of myFunc
grant("user1", VIEW_EXEC, "myFunc")
​
// grant user1 the execution privilege of f1 within dir1::myModule
grant("user1", VIEW_EXEC, "dir1::myModule::f1")
​
// grant user1 the execution privilege of all views within dir1::myModule
grant("user1", VIEW_EXEC, "dir1::myModule::*")

These privileges can be revoked or denied with revoke or deny.

To delete a function view, use dropFunctionView. For function views added by a module, you can either drop them independently by specifying the function name with its full namespace or remove them in batches by specifying the module namespace.

// drop the view of myFunc
dropFunctionView(name="myFunc")
​
// drop the view of f1 within dir1::myModule
dropFunctionView(name="dir1::myModule::f1")
​
// drop all views within dir1::myModule
dropFunctionView(name="dir1::myModule",isNamespace=true)

Note: Once a function view is added to a cluster, its definition cannot be modified. To update a view, you must delete the existing one, redefine the function, and add a new function view to the cluster.