Matrix

Use function matrix to create a matrix:

// create an integer matrix with all values set to the default value of 0
matrix(int, 2, 3);

// create a symbol matrix with all values set to the default value of NULL
matrix(symbol, 2, 3);

The matrix function can also create a matrix from vectors, matrices, table, tuple of vectors and their combination.

matrix(1 2 3);

matrix([1],[2])

matrix(1 2 3, 4 5 6);

matrix(table(1 2 3 as id, 4 5 6 as value));

matrix([1 2 3, 4 5 6]);

matrix([1 2 3, 4 5 6], 7 8 9);

matrix([1 2 3, 4 5 6], 7 8 9, table(0.5 0.6 0.7 as id), 1..9$3:3);

Statement X $ m:n or function cast(X, m:n) converts vector X into an m by n matrix.

m=1..10$5:2;
m;

cast(m,2:5);

DolphinDB is a column major system. Consecutive elements of columns are contiguous in memory. DolphinDB fills the elements in a matrix along the columns from the left to the right.

Use function rename! to add column names or row names to a matrix:

m1=1..9$3:3;
m1;

m1.rename!(`col1`col2`col3);

m1.rename!(1 2 3, `c1`c2`c3);

m1.colNames();
// output
["c1","c2","c3"]

m1.rowNames();
// output
[1,2,3]

Convert a matrix to a vector by function reshape or flatten

m1=1..6$3:2;
m2 = m1$2:3;
m2;

m=(1..6).reshape(3:2);
m;

y=m.reshape()
y;
// output
[1,2,3,4,5,6]

flatten m;
// output
[1,2,3,4,5,6]

Check dimensions ( shape), the number of rows( rows)and the number of columns ( cols):

m=1..10$2:5;
shape m;
// output
2 : 5

rows m
// output
2
cols m
// output
5

There are 2 ways to retrieve a cell: m.cell(row, col) or m[row, col].

m=1..12$4:3;
m;

m[1,2];
// output
10

m.cell(1,2);
// output
10

There are 2 ways to retrieve columns: m.col(index) where index is scalar/pair, and m[index] or m[, index] where index is scalar/pair/vector.

m=1..12$4:3;
m;

m[1];
// output
[5,6,7,8]
// select the column at position 1 to produce a vector

m[,1];
// select the column at position 1 to produce a sub matrix

m.col(2);
// output
[9,10,11,12]
// select the column at position 2

m[2:0];
// select the columns at position 1 and 0

m[1:3];
// select the columns at position 1 and 2

Please note that if index is a scalar, both m.col(index) and m[index] generate a vector whereas m[, index] generates a matrix.

m.col(1).typestr();
// output
FAST INT VECTOR

m[1].typestr();
// output
FAST INT VECTOR

m[,1].typestr();
// output
FAST INT MATRIX

There are 2 ways to retrieve rows: m.row(index) where index is scalar/pair, and m[index,] where index is scalar/pair/vector.

m=1..12$3:4;
m;

m[0,];
// return a sub matrix with row 0

// use function flatten to convert a matrix to a vector
flatten(m[0,]);
// output
[1,4,7,10]

// select row 2
m.row(2);
// output
[3,6,9,12]

// select rows 1 and 2.
m[1:3, ];

m[3:1, ];

There are 2 ways to retrieve a submatrix: m.slice(rowIndexRange,colIndexRange) and m[rowIndexRange,colIndexRange] where colIndex and rowIndex is scalar/pair. The upper bound is exclusive.

m=1..12$3:4;
m;

m.slice(0:2,1:3);

m[1:3,0:2];
// select rows 1 and 2, columns 0 and 1.

m[1:3,2:0];
// select rows 1 and 2, columns 1 and 0.

m[3:1,2:0];
// select rows 2 and 1, columns 1 and 0.

To append a matrix with a vector, the vector's size must be a multiple of the number of the rows of the matrix.

m=1..6$2:3;
m;

append!(m, 7 9);

append!(m, 8 6 1 2);
// appending m with two columns

append!(m, 3 4 5);
// output
The size of the vector to append must be divisible by the number of matrix rows.

Starting from version 2.00.4, you can use m[condition] = X for conditional assignment on a matrix, where condition is a Boolean matrix with the same shape as m. X is a scalar or vector. When X is a vector, the length must be the same as the number of true values in condition.

a = 1..12$3:4
a[a<5]=5

To modify a column, use m[index]=X where X is a scalar/vector.

t1=1..50$10:5;
t1;

// assign 200 to column 1
t1[1]=200;
t1;

// add 200 to column 1
t1[1]+=200;
t1;

// assign sequence 31..40 to column 1
t1[1]=31..40;
t1;

To modify multiple columns, use m[start:end] = X, where X is a scalar or vector.

t1=1..50$10:5;
t1;

// assign sequence 101..130 to columns 1,2,3
t1[1:4]=101..130;
t1;

// assign sequence 101..130 to columns 3,2,1
t1[4:1]=101..130;
t1;

// add 100 to columns 3,2,1
t1[4:1]+=100;
t1;

To modify a row, use m[index,] = X, where X is a scalar/vector.

t1=1..50$10:5;
// assign 100 to row 1
t1[1,]=100;
t1;

// add 100 to row 1
t1[1,]+=100;
t1;

To modify multiple rows, use m[start:end,] = X, where X is a scalar/vector.

t1=1..50$10:5;

// assign sequence 101..115 to columns 1 to 3
t1[1:4,]=101..115;
t1;

// assign sequence 101..115 to columns 3 to 1
t1[4:1, ]=101..115;
t1;

To modify an area in a matrix, use m[r1:r2, c1:c2] = X, where X is a scalar/vector.

t1=1..50$5:10;
//assign sequence 101..110 to the matrix window of row 1~2 and column 5~9
t1[1:3,5:10]=101..110;
t1;

t1=1..50$10:5;
// assign sequence 101..110 to the matrix window of row 5~9 and column 2~1
t1[5:10, 3:1]=101..110;
t1;

// add 10 to the matrix window of rows 9~5 and columns 1~2
t1[10:5, 1:3]+=10;
t1;

To update on specified elements of a matrix, use m[rowIndex,colIndex] = X, where rowIndex, colIndex and X can be a scalar/vector.

t1=1..20$4:5
t1[0 2, 0 2]=101;

t1;

t1[2 0, 2 0]=1001..1004;
t1;

We can use lambda expressions to remove certain columns of a matrix. Please note that for this usage the lambda expression can only accept one parameter, and the result must be a Boolean type scalar.

m=matrix(0 2 3 4,0 0 0 0,4 7 8 2);
m[x->!all(x==0)];
// return the columns that are not all 0s.

m=matrix(0 2 3 4,5 3 6 9,4 7 8 2);
m[def (x):avg(x)>4];
// return the columns with average value greater than 4.

Operations between a matrix and a scalar:

m=1..10$5:2;
m;

2.1*m;
// multiply 2.1 with each element in the matrix

m\2;

m+1.1;

m*NULL;
// the result is a NULL INT matrix

Operations between a matrix and a vector:

m=matrix(1 2 3, 4 5 6);
m;

m + 10 20 30;

m * 10 20 30;

Operations between matrices:

m1=1..10$2:5
m2=11..20$2:5;

m1+m2;
// element-wise addition

m1-m2;
// element-wise substract

m1*m2;
// element-wise multiplication

m2 = transpose(m2);

m1**m2;
// matrix multiplication

Matrix is a special case of vector. Therefore most vector functions can be applied to matrices.

m=1..6$2:3;
m;

// average of each row
avg(m);
// output
[1.5,3.5,5.5]

// sum of each row
sum(m);
// output
[3,7,11]

// cosine of each element
cos m;

To perform calculations on each column of a matrix, we can also use the template each.

We have the following matrix specific functions transpose, inverse(inv), det, diag and solve.

m=1..4$2:2;
transpose m;

inv(m);

det(m);
// output
-2

// solving m*x=[1,2]
m.solve(1 2);
// output
[1,0]

y=(1 0)$2:1;
y;

m**y;

diag(1 2 3);