addStatelessMetrics

语法

addStatelessMetrics(engine, metrics)

详情

向响应式无状态引擎中增加计算逻辑。

参数

engine 字符串标量或引擎对象,指定需要增加计算指标的响应式无状态引擎。

metrics 一个表,表示增加的计算逻辑:
  • formula:STRING 类型,表示计算逻辑。其中的变量采用 keyColumn 指定的列中的值标识,keyColumn 如不止一列,则使用 : 连接各值。

  • outputMetricKey:STRING 类型,为该计算指定指标名。

  • triggerOn:STRING 类型,表示触发该计算的数据标识,即 keyColumn 指定的列为该值时触发计算,keyColumn 如不止一列,则使用 : 连接各值 。

  • filter:一个数据对,表示计算结果的限定范围,属于该范围的结果才会被输出。

例子

先创建计算 factor1 + factor2 的响应式无状态引擎,再为其增加 factor1 * factor2 的计算规则。

// 创建输入、输出表和初始规则
inputTable = table(1:0, `metricKey`timestamp`value, [STRING, TIMESTAMP, DOUBLE])
outputTable = table(1:0, `metricKey`timestamp`value, [STRING, TIMESTAMP, DOUBLE])
initialMetrics = table(
    ['"factor1" + "factor2"'] as formula,
    ["value1"] as outputMetricKey,
    ["factor1"] as triggerOn,
    [0:100] as filter
)
statelessEngine = createReactiveStatelessEngine(
    name="factorMetricEngine", metrics=initialMetrics, outputTable=outputTable,
    dummyTable=inputTable, keyColumn="metricKey", timeColumn="timestamp"
)

// 新增规则:factor1 更新时计算乘积,仅输出 [10, 20] 内的结果
metricsTable = table(
    ['"factor1" * "factor2"'] as formula,
    ["value3"] as outputMetricKey,
    ["factor1"] as triggerOn,
    [10:20] as filter
)

addStatelessMetrics(statelessEngine, metrics=metricsTable)

// 写入数据,factor2 为 3,factor1 为 4
data = table(
    ["factor2", "factor1"] as metricKey,
    [2026.02.01T09:00:00.000, 2026.02.01T09:00:00.001] as timestamp,
    [3.0, 4.0] as value
)
statelessEngine.append!(newData=data)
result = select * from outputTable order by metricKey

// 清理本例创建的引擎,并查看结果
dropStreamEngine(name="factorMetricEngine")
result
metricKeytimestampvalue
value12026.02.01T09:00:00.0017
value32026.02.01T09:00:00.00112